Tem interesse em aprender mais sobre Mikrotik do início ao fim? Acesse esse link e conheça o Curso de MIKROTIK PROFISSIONAL com Leonardo Rosa.

Segue um passo a passo para configurar balanceamento entre 2 links com fail-over entre eles. Abaixo está um pequeno descritivo do cenário.

Entrada dos links: ether1 e ether2
LAN: bridge1
IPs:
  ether1: 172.16.0.2/30
  ether2: 172.16.1.2/30

O primeiro passo é criar as marcações dos pacotes que vão sair para uma das redes fornecidas pelos provedores.

/ip firewall mangle
add chain=prerouting dst-address=172.16.0.0/30  action=accept in-interface=bridge1
add chain=prerouting dst-address=172.16.1.0/30  action=accept in-interface=bridge1

Neste ponto marcamos os pacotes de entrada para que saiam para internet pela mesma porta que entraram, evitando problemas com acessos à sites/aplicações.

/ip firewall mangle
add chain=prerouting in-interface=ether1 connection-mark=no-mark action=mark-connection new-connection-mark=link_01
add chain=prerouting in-interface=ether2 connection-mark=no-mark action=mark-connection new-connection-mark=link_02

Aqui dividiremos o tráfego que sai da LAN para a WAN, através das marcações de roteamento.

/ip firewall mangle
add chain=prerouting  in-interface=bridge1 connection-mark=no-mark dst-address-type=!local per-connection-classifier=both-addresses:2/0 action=mark-connection new-connection-mark=link_01
add chain=prerouting  in-interface=bridge1 connection-mark=no-mark dst-address-type=!local per-connection-classifier=both-addresses:2/1 action=mark-connection new-connection-mark=link_02

Aqui marcamos os pacotes para que saiam para a internet e retornem pelo mesmo lini.

/ip firewall mangle
add chain=prerouting connection-mark=link_01 in-interface=bridge1 action=mark-routing new-routing-mark=to_ether1
add chain=prerouting connection-mark=link_02 in-interface=bridge1 action=mark-routing new-routing-mark=to_ether2
add chain=output connection-mark=link_01 action=mark-routing new-routing-mark=to_ether1
add chain=output connection-mark=link_02 action=mark-routing new-routing-mark=to_ether2

Aqui criamos os mascaramentos para os dois links, pode ser feito de forma mais refinada mas não é o objetivo deste passo a passo.

/ip firewall nat
add chain=srcnat out-interface=ether1 action=masquerade
add chain=srcnat out-interface=ether2 action=masquerade

Aqui vamos habilitar o fail-over, se uma rota cair a segunda rota passa a ser a utilizada para todas as saídas.

/ip route
add dst-address=0.0.0.0/0 gateway=172.16.0.1 distance=1 check-gateway=ping
add dst-address=0.0.0.0/0 gateway=172.16.1.1 distance=2 check-gateway=ping

Agora vamos criar as rotas usando as marcações que fizemos no mangle.

/ip route
add dst-address=0.0.0.0/0 gateway=172.16.0.1 routing-mark=to_ether1 check-gateway=ping
add dst-address=0.0.0.0/0 gateway=172.16.1.1 routing-mark=to_ether2 check-gateway=ping

Pronto, agora já pode desativar uma das rotas para testar.

OBS.: Se estiver fazendo essa configuração remotamente observe a rota que está usando para conectar no Mikrotik para não derrubar o seu acesso caso esteja com o “safe mode” ativado. Mesmo assim poderá conectar pela outra rota, caso não tenha feito a configuração com o “safe mode”.